// This macro labels the blobs from the 'Blobs' test image 
// according to their area.

  run("Set Measurements...", "area center redirect=None decimal=3");
  run("Blobs (25K)");
  setThreshold(125, 248);
  run("Analyze Particles...", 
    "minimum=1 maximum=999999 bins=20 show=Masks display exclude clear record");
  selectWindow("Mask of blobs.gif");
  run("16-bit");
  for (i=0; i<nResults; i++) {
      doWand(getResult("XStart",i), getResult("YStart", i));
      setColor(getResult("Area", i));
      fill();
  }
  run("Select None");
  resetMinAndMax();
